//invisdbl.txt
//This is a special case of abilswitch which is hardwired to switch between
//being invisible and doubling when struck.
// Memory Cells:
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;
short last_abil_time, l_switch_time;
short r1, current_abil;

body;

beginstate INIT_STATE;
	last_abil_time = get_current_tick();
	l_switch_time = get_current_tick();
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
		else
			set_target(ME,-1);
	}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
	}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
	}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 4)) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
	}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	if ((tick_difference(l_switch_time,get_current_tick()) >= 1)){
		if(current_abil == 29){
			set_special_ability(ME,24);
			current_abil = 24;
		}
		else{
			set_special_ability(ME,29);
			current_abil = 29;
		}
		l_switch_time = get_current_tick();
	}
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0)
		print_str("Talking: It doesn't respond.");
	else
		begin_talk_mode(get_memory_cell(3));
break;